// Downloaded at :   http://www.akbalder.com/ManiaPlanet/GameModes/ShootMania/GoalHuntArena.Script.txt



/* -------------------------------------- */
// Name: GoalHuntArena
// Version: 201305212109
// Author: Florian "Akbalder" Guillard
// Contact: akbalder@gmail.com
/* -------------------------------------- */

#RequireContext CSmMapType
#Include "TextLib" as TextLib
#Include "Libs/Nadeo/Anchor.Script.txt" as Anchor

declare Text Rules;

/* -------------------------------------- */
// Initialize the anchors
Void InitAnchors() {
	foreach (Data in AnchorData) {
		if(Data.DefaultTag=="Checkpoint"){ //replace "Checkpoint" by "Goal"
			Data.Tag = "Goal";
		}else{
			Data.Tag = Data.DefaultTag;
		}
		Data.Order = Data.DefaultOrder;
	}
}

/* -------------------------------------- */
// Check if the map is valid
Void UpdateValidability() {
	InitAnchors();
	Anchor::UpdateAnchorCounts();
	if (!Anchor::HasExactlyOneAnchor("Spawn", 0, _("You must place exactly one Spawn."))) return;
	if (!Anchor::HasAtLeastXAnchor("Goal", 0, 3, _("You must place at least 3 Goals."))) return;
}

/* -------------------------------------- */
// Manialink for non editable anchor
Text NoEditManialink() {
	return """
		<script><!--
			main() {
				declare Boolean Finish for Page;
				Finish = False;
				while(!Finish) {
					yield;

					foreach(Event in PendingEvents) {
						switch(Event.Type){
							case CMlEvent::Type::MouseClick : {
								Finish = True;
							}
						}
					}
				}
			}
		--></script>
		<frame posn="120 35">
			<quad posn="0 0 -1" sizen="70 15" halign="center" style="Bgs1" substyle="BgWindow2"/>
			<quad posn="0 0 2" sizen="74 15" halign="center" valign="bottom" style="Bgs1InRace" substyle="BgTitle3_5"/>
			<label posn="0 5.5 3" sizen="74 15" scale="0.9" halign="center" valign="bottom" style="TextTitle3" text="$fff{{{_("This anchor is not editable")}}}" />
			<label text="OK" posn="0 -3.5 3" halign="center" style="CardButtonMedium" ScriptEvents="true"/>
	    </frame>
		<frame posn="120 5">
			<quad posn="0 0 2" sizen="74 15" halign="center" valign="bottom" style="Bgs1InRace" substyle="BgTitle3_5"/>
			<label posn="0 5 3" halign="center" valign="bottom" style="TextTitle3" text="$fff{{{_("Rules")}}}" />
			<quad posn="0 0 -1" sizen="70 30" halign="center" style="Bgs1" substyle="BgWindow2"/>
			<frame posn="-30 -4">
				<label posn="0 0" sizen="60 5" autonewline="1" style="TextCardSmallScores2" text="$222{{{ Rules }}}" />
			</frame>
		</frame>
	""";
}

/* -------------------------------------- */
// Show the anchor edition manialink
Void EditAnchorData(Ident _EditedAnchorDataId)
{
	declare Integer AnchorOrder for ManialinkPage;
	declare Boolean Finish for ManialinkPage;
  ManialinkText = NoEditManialink();

	Finish = False;
	while(!Finish) {
		yield;
	}

	UpdateValidability();
}


/* -------------------------------------- */
// Main
/* -------------------------------------- */

main() {
	UpdateValidability();
	CustomEditAnchorData = True;
	Rules = _("You must place exactly one Spawn and at least three Goals.");
	while (True) {
		yield;
		ManialinkText = "";
		foreach(Event in PendingEvents) {
			if(Event.Type == CPluginEvent::Type::MapModified) {
				UpdateValidability();
			} else if (Event.Type == CPluginEvent::Type::EditAnchor) {
				EditAnchorData(Event.EditedAnchorDataId);
			}
		}
	}
}