// Downloaded at :    http://www.akbalder.com/ManiaPlanet/GameModes/ShootMania/JailbreakArena.Script.txt



/* -------------------------------------- */
// Name: JailbreakArena
// Version: 201403281108
// Author: Florian "Akbalder" Guillard
// Contact: akbalder@gmail.com
// Description: MapType for Jailbreak
// Details: One spawn, one goal and one jailspawn for each clan
/* -------------------------------------- */

#RequireContext CSmMapType
#Const Version			"2014-03-28"
#Const MapTypeVersion	1
#Const ScriptName		"JailbreakArena.Script.txt"

#Include "TextLib" as TextLib
#Include "Libs/Nadeo/Anchor.Script.txt" as Anchor
#Include "Libs/Nadeo/MapType.Script.txt" as MapType

// ---------------------------------- //
// Globales
// ---------------------------------- //
declare Text Rules;

// ---------------------------------- //
// Functions
// ---------------------------------- //
// ---------------------------------- //
// Initialize the anchors
Void InitAnchors() {
	foreach (Anchor in AnchorData) {
		if (Anchor.DefaultTag == "Spawn") {
			if (Anchor.Tag != "Spawn" && Anchor.Tag != "JailSpawn") Anchor.Tag = Anchor.DefaultTag;
			if (Anchor.Order != 1 && Anchor.Order != 2) Anchor.Order = 1;   
		} else if (Anchor.DefaultTag == "Goal") {
			Anchor.Tag = Anchor.DefaultTag;
			if (Anchor.Order != 1 && Anchor.Order != 2) Anchor.Order = 1;
		}else {
			Anchor.Tag = Anchor.DefaultTag;
			Anchor.Order = Anchor.DefaultOrder;
		}
	}
}

// ---------------------------------- //
// Check if the map is valid
Void UpdateValidability() {
	InitAnchors();
	
	Anchor::UpdateAnchorCounts();

	for(I, 1, 2) {
		if (!Anchor::HasExactlyOneAnchor("Spawn", I, TextLib::Compose(_("You must place exactly one Spawn #%1"), TextLib::ToText(I)))) return;
		if (!Anchor::HasExactlyOneAnchor("Goal", I, TextLib::Compose(_("You must place exactly one Goal #%1"), TextLib::ToText(I)))) return;
		if (!Anchor::HasExactlyOneAnchor("JailSpawn", I, TextLib::Compose(_("You must place exactly one JailSpawn #%1"), TextLib::ToText(I)))) return;
	}
	
	ValidationStatus = CSmMapType::ValidationStatus::Validated;	
}


// ---------------------------------- //
// Return the manialink for goal anchor edition
Text EditGoalAnchorManialink() {

	declare MLText =
	"""
	<script><!--
		#Include "TextLib" as TextLib

		main() {
			declare Buttons = [
			(Page.GetFirstChild("1") as CMlLabel),
			(Page.GetFirstChild("2") as CMlLabel)];

			declare Integer AnchorOrder for Page;
			declare Text	AnchorTag for Page;
			declare Boolean Finish for Page;
			Finish = False;
			while(!Finish) {
				yield;
				foreach(Button in Buttons) {
					if(AnchorOrder == TextLib::ToInteger(Button.ControlId))
						Button.Value = "$090Goal "^Button.ControlId;
					else
						Button.Value = "$fffGoal "^Button.ControlId;
				}

				foreach(Event in PendingEvents) {
					switch(Event.Type){
						case CMlEvent::Type::MouseClick : {
							if (Event.ControlId != "Cancel") AnchorOrder = TextLib::ToInteger(Event.ControlId);
							Finish = True;
						}
					}
				}
			}
		}
	--></script>
	<frame posn="120 35">
		<quad posn="0 0 -1" sizen="70 31" halign="center" style="Bgs1" substyle="BgWindow2"/>
		<quad posn="0 0 2" sizen="74 15" halign="center" valign="bottom" style="Bgs1InRace" substyle="BgTitle3_5"/>
		<label posn="0 5 3" halign="center" valign="bottom" style="TextTitle3" textprefix="$fff" text="{{{TextLib::Compose("%1 Goal", _("Edit"))}}}" />
		<frame posn="0 -4">
			<label id="1" posn="0 0" scale="2" halign="center" style="TextButtonMedium" ScriptEvents="true"/>
			<label id="2" posn="0 -8" scale="2" halign="center" style="TextButtonMedium" ScriptEvents="true"/>
		</frame>
		<label id="Cancel" text="{{{_("Cancel")}}}" posn="0 -21" halign="center" style="CardButtonSmall" ScriptEvents="true"/>
    </frame>
	<frame posn="120 -11">
		<quad posn="0 0 2" sizen="74 15" halign="center" valign="bottom" style="Bgs1InRace" substyle="BgTitle3_5"/>
		<label posn="0 5 3" halign="center" valign="bottom" style="TextTitle3" textprefix="$fff" text="{{{_("Rules")}}}" />
		<quad posn="0 0 -1" sizen="70 30" halign="center" style="Bgs1" substyle="BgWindow2"/>
		<frame posn="-30 -4">
			<label posn="0 0" sizen="60 5" autonewline="1" style="TextCardSmallScores2" textprefix="$222" text="{{{ Rules }}}" />
		</frame>
	</frame>
	""";

	return MLText;
}

// ---------------------------------- //
// Return the manialink for spawn anchor edition
Text EditSpawnAnchorManialink() {

	declare MLText =
	"""
	<script><!--
		#Include "TextLib" as TextLib

		main() {
			declare Buttons = [
			(Page.GetFirstChild("Spawn 1") as CMlLabel),
			(Page.GetFirstChild("Spawn 2") as CMlLabel),
			(Page.GetFirstChild("JailSpawn 1") as CMlLabel),
			(Page.GetFirstChild("JailSpawn 2") as CMlLabel)];


			declare Integer AnchorOrder for Page;
			declare Text	AnchorTag for Page;
			declare Boolean Finish for Page;
			Finish = False;
			while(!Finish) {
				yield;
				foreach(Button in Buttons) {
					if(AnchorTag^" "^AnchorOrder == Button.ControlId)
						Button.Value = "$090"^Button.ControlId;
					else
						Button.Value = "$fff"^Button.ControlId;
				}

				foreach(Event in PendingEvents) {
					switch(Event.Type){
						case CMlEvent::Type::MouseClick : {
							declare TagNames = ["Spawn", "JailSpawn"];
							foreach(TagName in TagNames){
								for(I, 1, 2) {
									if(Event.ControlId == TagName^" "^I) {
										AnchorTag = TagName;
										AnchorOrder = I;
									}
								}
							}
							Finish = True;
						}
					}
				}
			}
		}
	--></script>
	<frame posn="120 35">
		<quad posn="0 0 -1" sizen="70 47" halign="center" style="Bgs1" substyle="BgWindow2"/>
		<quad posn="0 0 2" sizen="74 15" halign="center" valign="bottom" style="Bgs1InRace" substyle="BgTitle3_5"/>
		<label posn="0 5 3" halign="center" valign="bottom" style="TextTitle3" textprefix="$fff" text="{{{TextLib::Compose("%1 Spawn", _("Edit"))}}}" />
		<frame posn="0 -4">
			<label id="Spawn 1" posn="0 0" scale="1.5" halign="center" style="TextButtonMedium" ScriptEvents="true"/>
			<label id="Spawn 2" posn="0 -8" scale="1.5" halign="center" style="TextButtonMedium" ScriptEvents="true"/>
			<label id="JailSpawn 1" posn="0 -16" scale="1.5" halign="center" style="TextButtonMedium" ScriptEvents="true"/>
			<label id="JailSpawn 2" posn="0 -24" scale="1.5" halign="center" style="TextButtonMedium" ScriptEvents="true"/>
		</frame>
		<label id="Cancel" text="{{{_("Cancel")}}}" posn="0 -37" halign="center" style="CardButtonSmall" ScriptEvents="true"/>
	</frame>
	<frame posn="120 -27">
		<quad posn="0 0 2" sizen="74 15" halign="center" valign="bottom" style="Bgs1InRace" substyle="BgTitle3_5"/>
		<label posn="0 5 3" halign="center" valign="bottom" style="TextTitle3" textprefix="$fff" text="{{{_("Rules")}}}" />
		<quad posn="0 0 -1" sizen="70 30" halign="center" style="Bgs1" substyle="BgWindow2"/>
		<frame posn="-30 -4">
			<label posn="0 0" sizen="60 5" autonewline="1" style="TextCardSmallScores2" textprefix="$222" text="{{{ Rules }}}" />
		</frame>
	</frame>
	""";

	return MLText;
}

// ---------------------------------- //
// Manialink for non editable anchor
Text NoEditManialink() {
	return """
<frame posn="120 35">
	<quad posn="0 0 -1" sizen="70 15" halign="center" style="Bgs1" substyle="BgWindow2"/>
	<quad posn="0 0 2" sizen="74 15" halign="center" valign="bottom" style="Bgs1InRace" substyle="BgTitle3_5"/>
	<label posn="0 5.5 3" scale="0.9" halign="center" valign="bottom" style="TextTitle3" textprefix="$fff" text="{{{_("This anchor is not editable")}}}" />
	<label text="OK" posn="0 -3.5 3" halign="center" style="CardButtonMedium" ScriptEvents="true"/>
</frame>
<frame posn="120 5">
	<quad posn="0 0 2" sizen="74 15" halign="center" valign="bottom" style="Bgs1InRace" substyle="BgTitle3_5"/>
	<label posn="0 5 3" halign="center" valign="bottom" style="TextTitle3" textprefix="$fff" text="{{{_("Rules")}}}" />
	<quad posn="0 0 -1" sizen="70 55" halign="center" style="Bgs1" substyle="BgWindow2"/>
	<frame posn="-30 -4">
		<label posn="0 0" sizen="60 5" autonewline="1" style="TextCardSmallScores2" textprefix="$222" text="{{{ Rules }}}" />
	</frame>
</frame>
<script><!--
main() {
	declare Boolean Finish for Page;
	Finish = False;	
	while(!Finish) {
		yield;
		
		foreach(Event in PendingEvents) {
			switch(Event.Type){
				case CMlEvent::Type::MouseClick : {
					Finish = True;
				}	
			}
		}
	}
}
--></script>
""";
}

// ---------------------------------- //
// Show the anchor edition manialink
Void EditAnchorData(Ident _EditedAnchorDataId)
{	
	UpdateValidability();
	declare Text AnchorTag for ManialinkPage;
	declare Integer AnchorOrder for ManialinkPage;
	declare Boolean Finish for ManialinkPage;
	
	declare DefaultTag = AnchorData[_EditedAnchorDataId].DefaultTag;
	if (DefaultTag == "Goal") ManialinkText = EditGoalAnchorManialink();
	else if(DefaultTag == "Spawn") ManialinkText = EditSpawnAnchorManialink();
	else ManialinkText = NoEditManialink();
	
	AnchorTag = AnchorData[_EditedAnchorDataId].Tag;
	AnchorOrder = AnchorData[_EditedAnchorDataId].Order;
	Finish = False;
	while(!Finish) {
		yield;
	}
	AnchorData[_EditedAnchorDataId].Tag = AnchorTag;
	AnchorData[_EditedAnchorDataId].Order = AnchorOrder;
	UpdateValidability();
}

// ---------------------------------- //
// Main
// ---------------------------------- //
main() {
	MapType::SetVersion(MapTypeVersion);
	
	UpdateValidability();
	CustomEditAnchorData = True;
	Rules = _("You must place exactly one Spawn #1 and one Spawn #2.\nYou must place exactly one Goal #1 and one Goal #2.\nYou must place exactly one JailSpawn #1 and one JailSpawn #2.");
	while (True) {	
		yield;
		ManialinkText = "";			
		foreach(Event in PendingEvents) {
			if(Event.Type == CPluginEvent::Type::MapModified) {
				UpdateValidability();			
			} else if(Event.Type == CPluginEvent::Type::EditAnchor) {
				EditAnchorData(Event.EditedAnchorDataId);
			}
		}		
	}	
}